home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / demo1078.cir < prev    next >
Encoding:
Text File  |  1996-07-09  |  3.8 KB  |  114 lines
  1. LT1078 FW Rect. ((Out=V(7); ref. ds circuit)
  2. *
  3. *                            Walt Jung
  4. *            LT1078 single-supply full wave rectifier circuit
  5. *                            06/28/90
  6. *
  7. * This circuit is an example of one which capitalizes on some
  8. * unique features of LTC single-supply op amps, as shown in a
  9. * data sheet application.  The circuit in question is shown on
  10. * p 2-262 (middle) of the LTC 1990 data book.
  11. *
  12. * This circuit is a absolute value or full wave rectifier,
  13. * operating from a single +5V supply.  In so doing, it handles
  14. * bipolar inputs of +/-3.5V up to 100Hz, delivering rectified 0 to
  15. * +3.5V output.  It is interesting just how well the LTC
  16. * macromodel allows the simulation to mimic the real LT1078
  17. * devices.  The model's output ranges for both the negative rail
  18. * (ground) range as well as the positive range are taxed, yet the
  19. * displayed result matches the data sheet performance quite well.
  20. * (Note that for a 3.5V peak output, amplifier stage one of the
  21. * simulation must swing to less than 1V from the positive rail.)
  22. *
  23. * In this demo, the Probe CMD file supplied calls up display parameters
  24. * which show dual plots of the input (bottom) and the rectified
  25. * output (top).
  26. *
  27. .OPT ACCT LIST NODE OPTS NOPAGE
  28. .WIDTH OUT=80 
  29. .TEMP 27
  30. VSIN1 100 0 sin(0 3.5V 100hertz 0)
  31. .TRAN 1u 10000u
  32. .PROBE
  33. R1    100  2  200e3
  34. R2    2    5  200e3
  35. D1    1    5  dm2
  36. R3    7    6  1e-3      ; jumper
  37. R4    3    0  1e-3      ; jumper
  38. VCC  52  0  5V
  39. XU1 3 2 52 0 1 LT1078
  40. XU2 5 6 52 0 7 LT1078
  41. *
  42. .MODEL DM2 D   (IS=8.000E-16)
  43. .SUBCKT LT1078 3 2 7 4 6
  44. RC1 4 80 2.653E+04
  45. RC2 4 90 2.653E+04
  46. Q1 80 102 10 QM1 
  47. Q2 90 103 11 QM2 
  48. RB1 2 102 6.000E+02
  49. RB2 3 103 6.000E+02
  50. DCM1 105 102 DM2 
  51. DCM2 105 103 DM2 
  52. VCMC 105 4 4.000E-01
  53. C1 80 90 8.660E-12
  54. RE1 10 12 4.958E+03
  55. RE2 11 12 4.958E+03
  56. IEE 7 12 2.412E-06
  57. RE 12 0 8.292E+07
  58. CE 12 0 1.579E-12
  59. GCM 0 8 12 0 1.501E-10
  60. GA 8 0 80 90 3.770E-05
  61. R2 8 0 1.000E+05
  62. C2 1 8 3.000E-11
  63. GB 1 0 8 0 2.449E+02
  64. RO1 1 110 1.000E+02
  65. RO2A 1 0 1.083E+03
  66. RO2B 6 110 8.170E+02
  67. EC 17 0 110 0 1 
  68. D1 1 17 DM1 
  69. D2 17 1 DM1 
  70. D3 110 13 DM2 
  71. D4 14 110 DM2 
  72. D5 6 110 DM2 
  73. D6 110 6 DM2 
  74. VC 7 13 1.490E+00
  75. VE 14 4 7.911E-01
  76. IP 7 4 4.259E-05
  77. DSUB 4 7 DM2 
  78. .MODEL QM1 PNP (IS=8.000E-16 BF=1.992E+02)
  79. .MODEL QM2 PNP (IS=8.012E-16 BF=2.008E+02)
  80. .MODEL DM1 D (IS=3.718E-24)
  81. .MODEL DM2 D (IS=8.000E-16)
  82. .ENDS LT1078
  83. **
  84. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1990
  85. *                       All rights reserved.
  86. * 
  87. *   Linear Technology Corporation hereby grants the users of this
  88. * macromodel a non-exclusive, nontransferrable license to use this
  89. *            macromodel under the following conditions:
  90. * 
  91. * The user agrees that this macromodel is licensed from Linear
  92. * Technology and agrees that the macromodel may be used, loaned,
  93. * given away or included in other model libraries as long as this
  94. * notice and the model in its entirety and unchanged is included.
  95. * No right to make derivative works or modifications to the
  96. * macromodel is granted hereby.  All such rights are reserved.
  97. * 
  98. * This model is provided as is.  Linear Technology makes no
  99. * warranty, either expressed or implied about the suitability or
  100. * fitness of this model for any particular purpose.  In no event
  101. * will Linear Technology be liable for special, collateral,
  102. * incidental or consequential damages in connection with or arising
  103. * out of the use of this macromodel.  It should be remembered that
  104. * models are a simplification of the actual circuit.
  105. * 
  106. * Linear Technology reserves the right to change these macromodels
  107. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  108. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  109. * datasheets on the actual amplifiers or the latest macromodels.
  110. * 
  111. * ----------------------------------------------------------------------- *
  112. .END
  113.  
  114.